6.02 Final
;Leave above line alone =) it's the version # that the script reads for itself =P 
;(easier than changing it throughout the script)
;
;*** DCC-Counter By Evil-Dragon ***
;*** This addon for mIRC requires mIRC Version 5.9 or higher! ***
;
; ** WEBSITE: http://www.evil-dragon.co.uk/myprojects.php **
;
; 5.64       || Fixed a slight bug with the colour settings, users could not use different backgrounds in their left and right graphics. 
;            || This has now been changed so you can do this.
; 5.65       || Features added, Time spent and received statistics & 6 new themes!! 
; 5.66       || Spelling mistakes! Arghhhh!! Also added support for directories with spaces in due to many troubles by users, sorry!
;            ||
; 6.00       || Added support for channel names, no need to have SpR Jukebox now, you can use ANY fileservinf script you want!
;            || Changed some options so that they save to the ini file, better than using variables and it will reload your choices
;            || if you have to reinstall mIRC!
; 6.01       || Titlebar timer was killing serving scripts due to updating every second, timer is now removed and
;            || it updates the titlebar when a file is sent/recieved instead. Also added 3 extra SpR themes.
; 6.02       || Bug fixed regarding DCC-Counter sending complete/failed messages to channels that it shouldn't and was annoying chat channels.
;            ||
; 6.02 Final || End of development. No more support, no more updates.
;
; IMPORTANT: To ensure official updates of this script always get this script from http://www.evil-dragon.co.uk/dcc-counter/
;            Changed scripts could contain undesirable effects, virus/trojan code or unwanted changes.
;
; Special thanks to: 
; Owner & Head Scripter:      Evil-Dragon 
; Bug Fixes & Helper:         |M|A|T|R|I|X| 
; Help, Support, BETA Tests:  The #mp3z-techno-dance Operators on Undernet (yes that includes you Maxisaitech!)
;                             and also to anyone else who i didn't mention who took part on the project and made suggestions!

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::;;;;;;;;;;; Load and Start/Connect Remote ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

on *:LOAD: {  
  echo -a [Info] Loading DCC-Counter V $+ $DCC.ScriptVer $+  by Evil-Dragon (Undernet)
  echo -a [Info] Access the DCC-Counter menu through right clicking in a channel
  echo -a [Info] or via the main mIRC "Commands" menu.
  DCC.Checkme
}

on *:CONNECT: { DCC.Checkme }

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: Local Alias(es) (-l) ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

alias -l DCC.Logfile { return " $+ $scriptdir $+ dcc-counter.ini" }

alias -l DCC.Checkme {
  if ($version < 5.9) { echo -a Sorry DCC-Counter requires an mIRC Version of 5.9 or later! Go get the new mIRC from http://www.mirc.com | unload -rs $script }

  if ($isfile($DCC.Logfile) = $false) { 
    writeini $DCC.Logfile Totals TotalRecieved 0
    writeini $DCC.Logfile Totals TotalSent 0
    writeini $DCC.Logfile Totals TimeRecieved 0
    writeini $DCC.Logfile Totals TimeSent 0
    writeini $DCC.Logfile Totals Numsent 0
    writeini $DCC.Logfile Totals Numrecieved 0 
    writeini $DCC.Logfile Date DateStart $date
    writeini $DCC.Logfile ScriptSent Number 0
    writeini $DCC.Logfile MaxSize Sent 0
    writeini $DCC.Logfile MaxSize Recieved 0
  }

  DCC.ChkDate
  if ($exists(" $+ $scriptdir $+ skins") == $false) { mkdir " $+ $scriptdir $+ skins" }
  if (%SMP3.CNTR.date == $null) { set %SMP3.CNTR.date $date | writeini $DCC.Logfile Date DateStart $date }
  if (%smp3.stats.timer == $null) || (%smp3.stats.timer !isnum) || (%smp3.stats.timer = 0) { set %smp3.stats.timer 3600 }
  if (%smp3.ad.timer == $null) || (%smp3.ad.timer !isnum) || (%smp3.ad.timer = 0) { set %smp3.ad.timer 1900 }
  if (%SMP3.CNTR.highlight == $null) { smp3.resetcolour }
  if (%SMP3.CNTR.left == $null) { set %SMP3.CNTR.left 14«2§5[ }
  if (%SMP3.CNTR.right == $null) { set %SMP3.CNTR.right 5]2§14» } 
  if (%SMP3.CNTR.tbar $readini $DCC.Logfile Options Titlebar = $null) { writeini $DCC.Logfile Options Titlebar Off }
  if ($readini $DCC.Logfile Options Advert == $null) { writeini $DCC.Logfile Options Advert Off }
  if ($readini $DCC.Logfile Options Stats == $null) { writeini $DCC.Logfile Options Stats On }
  if ($readini $DCC.Logfile Options DownloadLog == $null) { writeini $DCC.Logfile Options DownloadLog Off }
  if ($readini $DCC.Logfile Options UploadLog == $null) { writeini $DCC.Logfile Options UploadLog Off }
  if ($readini $DCC.Logfile Options Advert == On) { .timersmp3.counterad 0 %smp3.ad.timer smp3.counteradvert }
  if ($readini $DCC.Logfile Options Stats == On) { .timersmp3.quickstats 0 %smp3.stats.timer smp3.displaysent }
  set %SMP3.CNTR.b.recd $readini $DCC.Logfile Totals TotalRecieved
  set %SMP3.CNTR.b.sent $readini $DCC.Logfile Totals TotalSent
  set %SMP3.CNTR.f.sent $readini $DCC.Logfile Totals Numsent
  set %SMP3.CNTR.f.recd $readini $DCC.Logfile Totals Numrecieved
  set %smp3.CNTR.t.recd $readini $DCC.Logfile Totals TimeRecieved
  set %smp3.CNTR.t.sent $readini $DCC.Logfile Totals TimeSent
  set %smp3.scriptsent $readini $DCC.Logfile ScriptSent Number
  set %smp3.CNTR.maxrecd $readini $DCC.Logfile MaxSize Recieved
  set %smp3.CNTR.maxsent $readini $DCC.Logfile MaxSize Sent
  if ($readini $DCC.Logfile Channels Chan0 == $null) { echo -a [Info] You have NO SERVING CHANNELS added for DCC-Counter, please add one! | /dialog -m DCC_Counter_Config DCC_Counter_Config }
}

alias -l DCC.CommonChannel {
  %dc.iii = 0
  :checkchan
  %_SMP3.Temp1 = $readini $DCC.Logfile Channels Chan $+ [ %dc.iii ]
  if (%_SMP3.Temp1) { 
    if ($comchan($nick,1) = $null) {
      if ($comchan($me,1) = %_SMP3.Temp1) { return $comchan($me,1) }
      else {
        inc %dc.iii 1
        goto checkchan
      }
    }
    else {
      if ($comchan($nick,1) = %_SMP3.Temp1) { return $comchan($nick,1) }
      else {
        inc %dc.iii 1
        goto checkchan 
      }
    }
  }
  else { return $readini $DCC.Logfile Channels Chan0 }  
}


alias -l DCC.ChkDate {
  set %SMP3.dchk.date $readini $DCC.Logfile Date DateStart
  if ((%SMP3.dchk.date = $null) && (%SMP3.CNTR.date != $null)) { writeini $DCC.Logfile Date DateStart %SMP3.CNTR.date }
  if ((%SMP3.dchk.date != $null) && (%SMP3.CNTR.date = $null)) { set %SMP3.CNTR.date %SMP3.dchk.date }
  unset %SMP3.dchk.date
}

alias -l DCC.Mass {
  if ($version > 5.51) tokenize 32 $1- | %dc.w = 1
  :loop
  %ww = $gettok($1,%dc.w,44)
  if (%ww == $null) { unset %w %ww }
  else { echo $colour(normal text) %ww < $+ $me $+ > $2- | inc %dc.w 1 | goto loop }
  .raw -q privmsg $1 : $+ $2-
}

alias -l DCC.ScriptVer { return $read -l1 $script }
alias -l DCC.Convert { return $str(0,$calc(2 - $len($$1))) $+ $$1 }
alias smp3.dcctitlebar { titlebar - Nick: $me - Data Sent/Received: $round(%SMP3.CNTR.b.sent,0) MB ( $+ $round($calc(%SMP3.CNTR.b.sent /1000),2) GB) / $round(%SMP3.CNTR.b.recd,0) MB ( $+ $round($calc(%SMP3.CNTR.b.recd /1000),2) GB) }

alias -l DCC.ScriptUnload { 
  .timersmp3.quickstats off
  .timersmp3.counterad off
  unload -rs " $+ $script $+ "
}

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::: Dialogs and Events for Script  :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

dialog DCC_Counter_Config {
  title "DCC-Counter Configuration Dialog"
  size -1 -1 371 189
  option dbu
  box "Colour Configuration:", 1, 2 2 253 85
  button "Save", 3, 259 173 37 12, default ok
  button "Abandon", 4, 331 173 37 12, cancel
  combo 5, 32 26 60 53, size drop
  text "Text Colour", 6, 32 14 60 8, center
  combo 7, 100 26 60 53, size drop
  combo 8, 168 26 60 53, size drop
  text "Highlight Colour", 9, 101 14 60 8, center
  text "Background Colour", 10, 168 14 60 8, center
  box "Message And DCC Status Configuration:", 11, 2 131 253 57
  check "Titlebar Feature (Default: Off)", 14, 7 143 82 10
  check "DCC-Counter Advert (Default: On)", 15, 7 157 93 10
  check "DCC Send, Receive And Fail Msgs (Default: On)", 16, 7 171 127 10
  box "Left And Right Graphics", 12, 2 89 253 40
  edit "", 13, 40 111 79 10, autohs center
  text "Note: Use Ctrl+K to insert colour codes, use Ctrl+B for bold codes and use Ctrl+U for underline codes", 18, 7 97 243 8, center
  text "Left Graphic:", 19, 8 112 32 8
  text "Right Graphic:", 20, 126 112 35 8
  edit "", 21, 161 111 79 10, autohs center
  button "Preview Colours", 22, 293 134 44 12
  check "Download Log (Default: Off)", 2, 159 144 82 10
  check "Upload Log (Default: Off)", 17, 159 158 82 10
  box "Channel List:", 42, 258 2 112 127
  list 41, 262 27 67 96, size
  edit "", 43, 262 15 67 10
  button "Add", 44, 333 14 32 12
  button "Del", 45, 333 31 32 12
  menu "File", 23
  item "Load Theme", 24, 23
  item "Save Theme", 25, 23
  item "Reset Colours", 26, 23
  menu "Theme List", 27
  item "Default Theme", 28, 27
  item "Matrix Theme", 29, 27
  item "Blue Angel Theme", 30, 27
  item "The MTD Theme", 31, 27
  item "Orange Mp3z Theme", 32, 27
  item "Dark Blue Sea Theme", 33, 27
  item "Cold Aztec Theme", 34, 27
  item "DCC-Counter Gold", 35, 27
  item "Fading Fire Theme", 36, 27
  item "Fading Blue Theme", 37, 27
  item "Fading Green Theme", 38, 27
  item "Fading Sea Grey Theme", 39, 27
  item "Fading Purple Theme", 40, 27
  item "Traffic Lights Theme", 46, 27
  item "SpR Green Theme", 47, 27
  item "SpR Purple Theme", 48, 27
  item "SpR Red Theme", 49, 27
}

on *:DIALOG:DCC_Counter_Config:init:0: {
  %dc.i = 0
  :chan
  %_SMP3.Temp = $readini $DCC.Logfile Channels Chan $+ [ %dc.i ]
  if (%_SMP3.Temp) { did -a DCC_Counter_Config 41 %_SMP3.Temp | inc %dc.i 1 | goto chan }
  if ($readini $DCC.Logfile Options Titlebar == On) { did -c $dname 14 }
  if ($readini $DCC.Logfile Options Advert == On) { did -c $dname 15 }
  if ($readini $DCC.Logfile Options Stats == On) { did -c $dname 16 }
  if ($readini $DCC.Logfile Options DownloadLog == On) { did -c $dname 2 }
  if ($readini $DCC.Logfile Options UploadLog == On) { did -c $dname 17 } 
  did -a DCC_Counter_Config 13 %SMP3.CNTR.left
  did -a DCC_Counter_Config 21 %SMP3.CNTR.right
  smp3.preview.theme
  smp3.dbuildlist
}

on *:DIALOG:DCC_Counter_Config:menu:24: {
  set %smp3.theme.load $sfile(" $+ $scriptdir $+ skins\*.txt,Select a theme to load...,Load Theme)
  if ($read(%smp3.theme.load,1) = This_is_a_DCC-Counter_Theme) { 
    set %SMP3.CNTR.txt.colour $read(%smp3.theme.load,3)
    set %SMP3.CNTR.highlight $read(%smp3.theme.load,4)
    set %SMP3.CNTR.bg.colour $read(%smp3.theme.load,5)
    set %SMP3.CNTR.left $read(%smp3.theme.load,6)
    set %SMP3.CNTR.right $read(%smp3.theme.load,7)
    did -c DCC_Counter_Config 5 $calc(%SMP3.CNTR.txt.colour + 1)
    did -c DCC_Counter_Config 7 $calc(%SMP3.CNTR.highlight + 1)
    did -c DCC_Counter_Config 8 $calc(%SMP3.CNTR.bg.colour + 1)
    did -ra DCC_Counter_Config 13 %SMP3.CNTR.left 
    did -ra DCC_Counter_Config 21 %SMP3.CNTR.right
    smp3.preview.theme
    echo -a 14Loaded DCC-Counter Theme:12 $read(%smp3.theme.load,2)
  }
  else { echo -a 14Warning:12 This isn't a Valid DCC-Counter Theme! | halt } 
}

on *:DIALOG:DCC_Counter_Config:menu:25: {
  set %smp3.theme.save " $+ $scriptdir $+ skins\ $+ $$?="Please specify a filename for this theme... e.g. darkredtheme" $+ .txt"
  write -c %smp3.theme.save
  write %smp3.theme.save This_is_a_DCC-Counter_Theme
  write %smp3.theme.save $$?="Please give this theme a name... e.g. My Dark Red Theme"
  write %smp3.theme.save $did(5).text
  write %smp3.theme.save $did(7).text
  write %smp3.theme.save $did(8).text
  write %smp3.theme.save $did(13).text
  write %smp3.theme.save $did(21).text
  echo -a 14Saved DCC-Counter Theme:12 $read(%smp3.theme.save,2)
}

on *:DIALOG:DCC_Counter_Config:menu:26: {
  smp3.dresetcolours
}

on *:DIALOG:DCC_Counter_Config:menu:28: { did -c DCC_Counter_Config 5 1 | did -c DCC_Counter_Config 7 9 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 14«2§5[ | did -ra DCC_Counter_Config 21 5]2§14» | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:29: { did -c DCC_Counter_Config 5 4 | did -c DCC_Counter_Config 7 10 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 9«3§9[ | did -ra DCC_Counter_Config 21 9]3§9» | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:30: { did -c DCC_Counter_Config 5 12 | did -c DCC_Counter_Config 7 13 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 11~12Å11~ | did -ra DCC_Counter_Config 21 11~12Å11~ | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:31: { did -c DCC_Counter_Config 5 6 | did -c DCC_Counter_Config 7 8 | did -c DCC_Counter_Config 8 1 | did -ra DCC_Counter_Config 13 7.: MTD :. | did -ra DCC_Counter_Config 21 7.: MTD :. | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:32: { did -c DCC_Counter_Config 5 1 | did -c DCC_Counter_Config 7 8 |  did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 7«Mp3z» | did -ra DCC_Counter_Config 21 7«Mp3z» | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:33: { did -c DCC_Counter_Config 5 3 | did -c DCC_Counter_Config 7 13 | did -c DCC_Counter_Config 8 16 | did -ra DCC_Counter_Config 13 12«2§12[ | did -ra DCC_Counter_Config 21 12]2§12» | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:34: { did -c DCC_Counter_Config 5 11 | did -c DCC_Counter_Config 7 12 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 10«0§10[ | did -ra DCC_Counter_Config 21 10]0§10» | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:35: { did -c DCC_Counter_Config 5 9 | did -c DCC_Counter_Config 7 5 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 8[0DCC-Counter8] | did -ra DCC_Counter_Config 21 8[0Final Gold Version8] | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:36: { did -c DCC_Counter_Config 5 9 | did -c DCC_Counter_Config 7 1 | did -c DCC_Counter_Config 8 5 | did -ra DCC_Counter_Config 13 8,0 ,%0,8%`7,8,%8,7%`4,7,%7,4%`8,4 | did -ra DCC_Counter_Config 21 7,4`%4,7%,8,7`%7,8%,0,8`%8,0%,  | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:37: { did -c DCC_Counter_Config 5 12 | did -c DCC_Counter_Config 7 13 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 12,0-æ0,12æ¸2,12`æ12,2æ¸1,2`æ2,1æ¸0,1 | did -ra DCC_Counter_Config 21 2,1`æ1,2æ¸12,2`æ2,12æ¸0,12`æ12,0æ- | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:38: { did -c DCC_Counter_Config 5 10 | did -c DCC_Counter_Config 7 4 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 9,0æ0,9æ3,9æ9,3æ1,3æ3,1æ 9,1 | did -ra DCC_Counter_Config 21 3,1æ1,3æ9,3æ3,9æ0,9æ9,0æ | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:39: { did -c DCC_Counter_Config 5 12 | did -c DCC_Counter_Config 7 13 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 16,15%,14,15`%15,14%,10,14`%14,10%,2,10`%10,2%,15,2 | did -ra DCC_Counter_Config 21 10,2`%2,10%,14,10`%10,14%,15,14`%14,1516,1514,15`% 16,15%, | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:40: { did -c DCC_Counter_Config 5 14 | did -c DCC_Counter_Config 7 1 | did -c DCC_Counter_Config 8 7 | did -ra DCC_Counter_Config 13 15,0,%0,15%`13,15,%15,13%`6,13,%13,6%`5,6,% 8 | did -ra DCC_Counter_Config 21 5,6%,13,6`%6,13%,15,13`%13,15%,0,15`%15,0%, | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:46: { did -c DCC_Counter_Config 5 15 | did -c DCC_Counter_Config 7 5 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 4,1<8<9< | did -ra DCC_Counter_Config 21 9,1>8>4> | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:47: { did -c DCC_Counter_Config 5 10 | did -c DCC_Counter_Config 7 1 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 0,9(3)9,3(1)3,1(9,1 | did -ra DCC_Counter_Config 21 3,1)1,3(9)3,9(0) | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:48: { did -c DCC_Counter_Config 5 14 | did -c DCC_Counter_Config 7 1 | did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 0,13(6)13,6(1)6,1(13,1 | did -ra DCC_Counter_Config 21 6,1)1,6(13)6,13(0) | smp3.generate.preview }
on *:DIALOG:DCC_Counter_Config:menu:49: { did -c DCC_Counter_Config 5 5 | did -c DCC_Counter_Config 7 1 |  did -c DCC_Counter_Config 8 2 | did -ra DCC_Counter_Config 13 0,4<5>4,5<1>5,1< | did -ra DCC_Counter_Config 21 5,1>1,5<4>5,4<0> | smp3.generate.preview }

on *:DIALOG:DCC_Counter_Config:sclick:3: {
  if ($did(DCC_Counter_Config,14).state == 1) { writeini $DCC.Logfile Options Titlebar On }
  else { writeini $DCC.Logfile Options Titlebar Off }
  if ($did(DCC_Counter_Config,15).state == 1) { .timersmp3.counterad 0 %smp3.ad.timer smp3.counteradvert | writeini $DCC.Logfile Options Advert On }
  else { .timersmp3.counterad off | writeini $DCC.Logfile Options Advert Off }
  if ($did(DCC_Counter_Config,16).state == 1) { .timersmp3.quickstats 0 %smp3.stats.timer smp3.displaysent | writeini $DCC.Logfile Options Stats On }
  else { .timersmp3.quickstats Off | writeini $DCC.Logfile Options Stats Off }
  if ($did(DCC_Counter_Config,2).state == 1) { writeini $DCC.Logfile Options DownloadLog On }
  else { writeini $DCC.Logfile Options DownloadLog Off }
  if ($did(DCC_Counter_Config,17).state == 1) { writeini $DCC.Logfile Options UploadLog On }
  else { writeini $DCC.Logfile Options UploadLog Off }

  set %SMP3.CNTR.txt.colour $did(5).text
  set %SMP3.CNTR.highlight $did(7).text
  set %SMP3.CNTR.bg.colour $did(8).text
  set %SMP3.CNTR.left $did(13).text
  set %SMP3.CNTR.right $did(21).text

  unset %SMP3.CNTR.chan.* | %dc.i = 2 | %dc.k = 1 | set %SMP3.CNTR.Main $did(41,1) | set %SMP3.CNTR.chan.0 %SMP3.CNTR.Main
  remini $DCC.Logfile Channels
  writeini $DCC.Logfile Channels Chan0 %SMP3.CNTR.Main
  :cloop
  if ($did(41,%dc.i)) { 
    set %SMP3.CNTR.chan. [ $+ [ %dc.k ] ] $did(41,%dc.i)
    writeini $DCC.Logfile Channels Chan $+ [ %dc.k ] $did(41,%dc.i)
    inc %dc.i 1
    inc %dc.k 1
    goto cloop 
  }
  if (%dc.i < 3) { set %SMP3.CNTR.Chan.Type Main }
  else { set %SMP3.CNTR.Chan.Type Multi }
}

on *:DIALOG:DCC_Counter_Config:sclick:5,7,8,13,21: {
  set %SMP3.preview.txt.colour $did(5).text
  set %SMP3.preview.highlight $did(7).text
  set %SMP3.preview.bg.colour $did(8).text
}

on *:DIALOG:DCC_Counter_Config:edit:13,21: {
  set %SMP3.preview.left $did(13).text
  set %SMP3.preview.right $did(21).text
} 

on *:DIALOG:DCC_Counter_Config:sclick:22: {
  echo -a 4,2DCC-COUNTER COLOUR TEST: 1, $+ %SMP3.preview.bg.colour $+ %SMP3.preview.left $+  $+ %SMP3.preview.txt.colour $+ , $+ %SMP3.preview.bg.colour I have just finished sending $+ %SMP3.preview.highlight A really big MP3 File.mp3  $+ %SMP3.preview.txt.colour $+ ( $+ 103 MB) to $+ %SMP3.preview.highlight Mr_Rogers $+ .   $+ %SMP3.preview.txt.colour $+ I have now sent a total of $+ %SMP3.preview.highlight 4353  $+ %SMP3.preview.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.preview.highlight) $+ 4.3  $+ %SMP3.preview.txt.colour $+ GB) in $+ %SMP3.preview.highlight 3532 $+  $+ %SMP3.preview.txt.colour files since $+ %SMP3.preview.highlight 01/01/01 1, $+ %SMP3.preview.bg.colour $+ %SMP3.preview.right
}

on *:DIALOG:DCC_Counter_Config:sclick:45: /smp3.del.item 41

on *:DIALOG:DCC_Counter_Config:sclick:44: { 
  if (($did(43)) && ($left($did(43),1) == $chr(35))) { 
    %dc.i = 1
    :loop
    if ($did(41,%dc.i)) { if ($did(41,%dc.i) == $did(43)) { did -r DCC_Counter_Config 43 | halt } | inc %dc.i 1 | goto loop }
    did -a DCC_Counter_Config 41 $did(43) | did -r DCC_Counter_Config 43 
  } 
}

alias -l smp3.dbuildlist {
  did -a DCC_Counter_Config 5,7,8 0
  did -a DCC_Counter_Config 5,7,8 1
  did -a DCC_Counter_Config 5,7,8 2
  did -a DCC_Counter_Config 5,7,8 3
  did -a DCC_Counter_Config 5,7,8 4
  did -a DCC_Counter_Config 5,7,8 5
  did -a DCC_Counter_Config 5,7,8 6
  did -a DCC_Counter_Config 5,7,8 7
  did -a DCC_Counter_Config 5,7,8 8
  did -a DCC_Counter_Config 5,7,8 9
  did -a DCC_Counter_Config 5,7,8 10
  did -a DCC_Counter_Config 5,7,8 11
  did -a DCC_Counter_Config 5,7,8 12
  did -a DCC_Counter_Config 5,7,8 13
  did -a DCC_Counter_Config 5,7,8 14
  did -a DCC_Counter_Config 5,7,8 15
  did -c DCC_Counter_Config 5 $calc(%SMP3.CNTR.txt.colour + 1)
  did -c DCC_Counter_Config 7 $calc(%SMP3.CNTR.highlight + 1)
  did -c DCC_Counter_Config 8 $calc(%SMP3.CNTR.bg.colour + 1)
}

alias -l smp3.dresetcolours {
  did -c DCC_Counter_Config 5 1
  did -c DCC_Counter_Config 7 9
  did -c DCC_Counter_Config 8 2
  did -ra DCC_Counter_Config 13 14«2§5[ 
  did -ra DCC_Counter_Config 21 5]2§14» 
  smp3.resetcolour
  smp3.preview.theme
}

alias -l smp3.preview.theme {
  set %SMP3.preview.txt.colour %SMP3.CNTR.txt.colour
  set %SMP3.preview.highlight %SMP3.CNTR.highlight
  set %SMP3.preview.bg.colour %SMP3.CNTR.bg.colour
  set %SMP3.preview.left %SMP3.CNTR.left
  set %SMP3.preview.right %SMP3.CNTR.right
}

alias -l smp3.generate.preview {
  set %SMP3.preview.txt.colour $did(5).text
  set %SMP3.preview.highlight $did(7).text
  set %SMP3.preview.bg.colour $did(8).text
  set %SMP3.preview.left $did(13).text
  set %SMP3.preview.right $did(21).text
}

alias -l smp3.del.item {
  if ($version > 5.51) tokenize 32 $1-  
  if ($did($1,1).sel) {
    %dc.i = 1 | %dc.ii = $did($1,0).sel 
    :1
    if (%dc.i <= %dc.ii) { did -d DCC_Counter_Config $1 $did($1,1).sel | inc %dc.i 1 | goto 1 }
  }
}

dialog DCC_Counter_Stats {
  title "DCC-Counter Quick Stats"
  size -1 -1 277 136
  option dbu
  text "Data Sent:", 12, 9 26 27 8
  edit "", 13, 35 25 33 10, read autohs center
  text "MB", 18, 68 26 12 8, center
  edit "", 19, 35 36 33 10, read autohs center
  text "GB", 20, 68 37 12 8, center
  text "The collection of this data (statistics) was started on: ", 21, 48 12 125 8
  edit "", 22, 172 11 37 10, read center
  text "in", 23, 79 31 7 8, center
  edit "", 25, 87 30 28 10, read center
  text "files", 27, 116 31 12 8, center
  text "Data Received:", 29, 134 26 38 8
  edit "", 30, 172 25 33 10, read autohs center
  text "MB", 31, 206 26 12 8, center
  edit "", 32, 172 36 33 10, read autohs center
  text "GB", 33, 206 37 12 8, center
  text "in", 34, 217 31 7 8, center
  edit "", 36, 225 30 28 10, read center
  text "files", 38, 254 31 12 8, center
  box "DCC-Counter Statistics:", 40, 2 1 273 133
  button "OK", 3, 121 115 37 12, default ok cancel
  text "Largest File Sent:", 1, 32 56 44 8, right
  edit "", 2, 76 55 31 10, read center
  text "Largest File Received:", 4, 21 70 56 8, right
  edit "", 5, 76 69 31 10, read center
  text "Average Size of files sent are", 6, 141 55 71 8
  edit "", 7, 212 54 31 10, read center
  text "MB", 8, 243 55 12 8, center
  text "MB", 9, 107 56 12 8, center
  text "MB", 10, 107 70 12 8, center
  text "Average Size of files received are", 11, 130 70 82 8
  edit "", 14, 212 69 31 10, read center
  text "MB", 15, 243 70 12 8, center
  text "Time Spent Sending:", 24, 23 87 54 8, right
  edit "", 26, 77 86 166 10, read center
  text "Time Spent Receiving:", 16, 23 99 54 8, right
  edit "", 17, 77 98 166 10, read center
}

on *:DIALOG:DCC_Counter_Stats:init:0: {
  smp3.dquickstats
}

alias -l smp3.dquickstats {
  did -a DCC_Counter_Stats 13 $round(%SMP3.CNTR.b.sent,0)
  did -a DCC_Counter_Stats 19 $round($calc(%SMP3.CNTR.b.sent /1000),2)
  did -a DCC_Counter_Stats 30 $round(%SMP3.CNTR.b.recd,0)
  did -a DCC_Counter_Stats 32 $round($calc(%SMP3.CNTR.b.recd /1000),2)
  did -a DCC_Counter_Stats 25 %SMP3.CNTR.f.sent
  did -a DCC_Counter_Stats 36 %SMP3.CNTR.f.recd
  did -a DCC_Counter_Stats 22 %SMP3.CNTR.date
  did -a DCC_Counter_Stats 2 %smp3.CNTR.maxsent
  did -a DCC_Counter_Stats 5 %smp3.CNTR.maxrecd
  did -a DCC_Counter_Stats 7 %SMP3.CNTR.avg.sent
  did -a DCC_Counter_Stats 14 %SMP3.CNTR.avg.recd
  did -a DCC_Counter_Stats 17 $duration(%SMP3.CNTR.t.recd)
  did -a DCC_Counter_Stats 26 $duration(%SMP3.CNTR.t.sent)
}

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;:::::::::::::::::::::::::::::::::::::::::::::::::: Global Aliases for Displays :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

alias smp3.displaysent {
  set %SMP3.CNTR.dispsent 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have sent a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.sent,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.sent /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.sent  $+ %SMP3.CNTR.txt.colour $+ files and leeched a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.recd,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.recd /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.recd  $+ %SMP3.CNTR.txt.colour $+ files since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  set %SMP3.CNTR.dispsent2 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have spent a total time of $+ %SMP3.CNTR.highlight $duration(%smp3.CNTR.t.sent)  $+ %SMP3.CNTR.txt.colour $+ sending files and a total time of $+ %SMP3.CNTR.highlight $duration(%smp3.CNTR.t.recd)  $+ %SMP3.CNTR.txt.colour $+ recieving files. 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right 
  if (%SMP3.CNTR.Chan.Type = Main) { if ($me ison %SMP3.CNTR.Main) msg %SMP3.CNTR.Main %SMP3.CNTR.dispsent | if ($me ison %SMP3.CNTR.Main) msg %SMP3.CNTR.Main %SMP3.CNTR.dispsent2 | return }
  if (%SMP3.CNTR.Chan.Type = Multi) {
    unset %Put.MCHad | set %dc.i 0
    :multich
    set %Put.Temp %SMP3.CNTR.chan. [ $+ [ %dc.i ] ]
    if (%Put.Temp == $null) { unset %Put.Temp %dc.i | goto end }
    if ($me ison %Put.Temp) { set %Put.MCHad %Put.MCHad $+ $chr(44) $+ %Put.Temp }
    inc %dc.i 1 | goto multich
    :end
    if (%Put.MCHad) DCC.Mass %Put.MCHad %SMP3.CNTR.dispsent | DCC.Mass %Put.MCHad %SMP3.CNTR.dispsent2 | unset %Put.MCHad
  }  
}

alias smp3.counteradvert {
  set %smp3.CNTR.counterad 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour Do you want to keep track of your $+ %SMP3.CNTR.highlight DCC Sends $+ %SMP3.CNTR.txt.colour and $+ %SMP3.CNTR.highlight Receives $+ %SMP3.CNTR.txt.colour with $+ %SMP3.CNTR.highlight MB's $+ %SMP3.CNTR.txt.colour and numbers sent? $+ %SMP3.CNTR.highlight DCC-Counter $+ %SMP3.CNTR.txt.colour will do that for you! To get DCC-Counter off me type $+ %SMP3.CNTR.highlight @ $+ $me $+ -Counter $+ %SMP3.CNTR.txt.colour ( $+ %SMP3.CNTR.highlight $+ Version: V $+ $DCC.ScriptVer $+  $+ %SMP3.CNTR.txt.colour $+ ) 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  if (%SMP3.CNTR.Chan.Type = Main) { if ($me ison %SMP3.CNTR.Main) msg %SMP3.CNTR.Main %smp3.CNTR.counterad | return }
  if (%SMP3.CNTR.Chan.Type = Multi) {
    unset %Put.MCHad | set %dc.i 0
    :multich
    set %Put.Temp %SMP3.CNTR.chan. [ $+ [ %dc.i ] ]
    if (%Put.Temp = $null) { unset %Put.Temp %i | goto end }
    if ($me ison %Put.Temp) { set %Put.MCHad %Put.MCHad $+ $chr(44) $+ %Put.Temp }
    inc %dc.i 1 | goto multich
    :end
    if (%Put.MCHad) DCC.Mass %Put.MCHad %smp3.CNTR.counterad | unset %Put.MCHad
  }  
}

alias smp3.resetcolour { 
  set %SMP3.CNTR.bg.colour 1 
  set %SMP3.CNTR.txt.colour 0
  set %SMP3.CNTR.highlight 8
  set %SMP3.CNTR.left 14«2§5[
  set %SMP3.CNTR.right 5]2§14»
}

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;:::::::::::::::::::::::::::::::::::::::::::::::::::::::: File Events Remote ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

on *:FILERCVD:*: {
  set %temprecieved $round($calc($lof($filename)/1024000),2)
  if ((%temprecieved > %smp3.CNTR.maxrecd) || (%smp3.CNTR.maxrecd = $null)) { set %smp3.CNTR.maxrecd %temprecieved | writeini $DCC.Logfile MaxSize Recieved %smp3.CNTR.maxrecd }
  set %SMP3.CNTR.b.recd $readini $DCC.Logfile Totals TotalRecieved 
  inc %SMP3.CNTR.b.recd %temprecieved
  writeini $DCC.Logfile Totals TotalRecieved %SMP3.CNTR.b.recd
  set %SMP3.CNTR.f.recd $readini $DCC.Logfile Totals Numrecieved
  inc %SMP3.CNTR.f.recd 1
  writeini $DCC.Logfile Totals Numrecieved %SMP3.CNTR.f.recd
  set %smp3.CNTR.t.recd $readini $DCC.Logfile Totals TimeRecieved
  inc %smp3.CNTR.t.recd $get($nick).secs
  writeini $DCC.Logfile Totals TimeRecieved %smp3.CNTR.t.recd
  set %SMP3.CNTR.avg.recd $round($calc(%SMP3.CNTR.b.recd / %SMP3.CNTR.f.recd),2)
  if ($readini $DCC.Logfile Options Titlebar == On) smp3.dcctitlebar
  if ($readini $DCC.Logfile Options DownloadLog == On) write " $+ $scriptdir $+ download.txt" ( $+ $date $+ )( $+ $time $+ ) $nopath($filename) ( $+ %temprecieved MB) from $nick
  if ($readini $DCC.Logfile Options Stats == On) { 
    msg $DCC.CommonChannel 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have just finished recieving $+ %SMP3.CNTR.highlight $nopath($filename)  $+ %SMP3.CNTR.txt.colour $+ ( $+ %temprecieved MB) from $+ %SMP3.CNTR.highlight $nick  $+ %SMP3.CNTR.txt.colour $+ in $+ %SMP3.CNTR.highlight $duration($get($nick).secs)  $+ %SMP3.CNTR.txt.colour $+ at $+ %SMP3.CNTR.highlight $get($nick).cps  $+ %SMP3.CNTR.txt.colour $+ CPS.   $+ %SMP3.CNTR.txt.colour $+ I have now received a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.recd,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.recd /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.recd $+  $+ %SMP3.CNTR.txt.colour files since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  }
}

on *:Filesent:*: {
  if (dcc-counter.txt isin $nopath($filename)) {
    set %smp3.scriptsent $readini $DCC.Logfile ScriptSent Number
    inc %smp3.scriptsent 1 
    writeini $DCC.Logfile ScriptSent Number %smp3.scriptsent
    if ($readini $DCC.Logfile Options Stats == On) msg $DCC.CommonChannel 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have just finished sending $+ %SMP3.CNTR.highlight DCC-Counter  $+ %SMP3.CNTR.txt.colour $+ (Version: $+ %SMP3.CNTR.highlight V $+ $DCC.ScriptVer $+  $+ %SMP3.CNTR.txt.colour $+ ) to $+ %SMP3.CNTR.highlight $nick $+ .  $+ %SMP3.CNTR.txt.colour $+ I have now sent DCC-Counter $+ %SMP3.CNTR.highlight %smp3.scriptsent  $+ %SMP3.CNTR.txt.colour $+ times. 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right 
  }   
  else {
    set %tempsent $round($calc($lof($filename)/1024000),2)
    if ((%tempsent > %smp3.CNTR.maxsent) || (%smp3.CNTR.maxsent = $null)) { set %smp3.CNTR.maxsent %tempsent | writeini $DCC.Logfile MaxSize Sent %smp3.CNTR.maxsent }
    set %SMP3.CNTR.b.sent $readini $DCC.Logfile Totals TotalSent
    inc %SMP3.CNTR.b.sent %tempsent
    writeini $DCC.Logfile Totals TotalSent %SMP3.CNTR.b.sent
    set %SMP3.CNTR.f.sent $readini $DCC.Logfile Totals Numsent
    inc %SMP3.CNTR.f.sent 1
    writeini $DCC.Logfile Totals Numsent %SMP3.CNTR.f.sent
    set %smp3.CNTR.t.sent $readini $DCC.Logfile Totals TimeSent
    inc %smp3.CNTR.t.sent $send($nick).secs
    writeini $DCC.Logfile Totals TimeSent %smp3.CNTR.t.sent
    set %SMP3.CNTR.avg.sent $round($calc(%SMP3.CNTR.b.sent / %SMP3.CNTR.f.sent),2)
    if ($readini $DCC.Logfile Options Titlebar == On) smp3.dcctitlebar
    if ($readini $DCC.Logfile Options UploadLog == On) write " $+ $scriptdir $+ uploaded.txt" ( $+ $date $+ )( $+ $time $+ ) $nopath($filename) ( $+ %tempsent MB) to $nick
    if ($readini $DCC.Logfile Options Stats == On) {
      msg $DCC.CommonChannel 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have just finished sending $+ %SMP3.CNTR.highlight $nopath($filename)  $+ %SMP3.CNTR.txt.colour $+ ( $+ %tempsent MB) to $+ %SMP3.CNTR.highlight $nick  $+ %SMP3.CNTR.txt.colour $+ in $+ %SMP3.CNTR.highlight $duration($send($nick).secs)  $+ %SMP3.CNTR.txt.colour $+ at $+ %SMP3.CNTR.highlight $send($nick).cps  $+ %SMP3.CNTR.txt.colour $+ CPS.   $+ %SMP3.CNTR.txt.colour $+ I have now sent a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.sent,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.sent /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.sent $+  $+ %SMP3.CNTR.txt.colour files since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
    }  
  }
}

on *:SENDFAIL:*: if ($readini $DCC.Logfile Options Stats == On) { msg $DCC.CommonChannel 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour DCC Send $+ %SMP3.CNTR.highlight Failed $+ %SMP3.CNTR.txt.colour of $+ %SMP3.CNTR.highlight $nopath($filename) $+  $+ %SMP3.CNTR.txt.colour to $+ %SMP3.CNTR.highlight $nick $+ . 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right }
on *:GETFAIL:*: if ($readini $DCC.Logfile Options Stats == On) { msg $DCC.CommonChannel 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour DCC Get $+ %SMP3.CNTR.highlight Failed $+ %SMP3.CNTR.txt.colour of $+ %SMP3.CNTR.highlight $nopath($filename) $+  $+ %SMP3.CNTR.txt.colour from $+ %SMP3.CNTR.highlight $nick $+ . 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right }

on *:TEXT:@*:#: {
  if ($me isin $1) && ($right($1,7) = Counter) { 
    .msg $nick 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour REMEMBER to  $+ %SMP3.CNTR.highlight $+ UNLOAD  $+ %SMP3.CNTR.txt.colour $+ your old DCC-Counter script if you have used previous versions, once this file has been sent to you make sure you put it in your mIRC Directory. Type  $+ %SMP3.CNTR.highlight $+ /load -rs dcc-counter.txt  $+ %SMP3.CNTR.txt.colour $+ to load it! Thanks...  $+ %SMP3.CNTR.highlight $+ DCC-Counter Author $+ %SMP3.CNTR.txt.colour $+ : ( $+ %SMP3.CNTR.highlight $+ Evil-Dragon $+ %SMP3.CNTR.txt.colour $+ ) 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
    dcc send $nick $script
  }
}

ctcp *:VERSION:*: .ctcpreply $nick VERSION 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I'm using  $+ %SMP3.CNTR.highlight $+ DCC-Counter  $+ %SMP3.CNTR.txt.colour $+ (Version: $+ %SMP3.CNTR.highlight V $+ $DCC.ScriptVer $+  $+ %SMP3.CNTR.txt.colour $+ )  $+ %SMP3.CNTR.txt.colour $+ Author: ( $+ %SMP3.CNTR.highlight $+ Evil-Dragon  $+ %SMP3.CNTR.txt.colour $+ on Undernet) 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right | halt

on *:UNLOAD: { DCC.ScriptUnload }

;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;:::::::::::::::::::::::::::::::::::::::::::::::::::::: User Menuing Remote :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
;::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

menu channel,menubar {
  -
  -[DCC Counter]-
  .=-DCC Counter V $+ $DCC.ScriptVer $+ -=: /run http://www.evil-dragon.co.uk/dcc-counter/
  .-
  .All Quick Stats: {
    say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour All Statistics collected since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right 
    say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have sent a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.sent,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.sent /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.sent  $+ %SMP3.CNTR.txt.colour $+ files 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
    say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have received a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.recd,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.recd /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.recd  $+ %SMP3.CNTR.txt.colour $+ files 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right   
    say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The largest file I have sent/received was $+ %SMP3.CNTR.highlight %smp3.CNTR.maxsent $+  $+ %SMP3.CNTR.txt.colour $+ / $+  $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ %smp3.CNTR.maxrecd  $+ %SMP3.CNTR.txt.colour $+ MB 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
    say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The average size of a file sent/received is $+ %SMP3.CNTR.highlight %SMP3.CNTR.avg.sent $+  $+ %SMP3.CNTR.txt.colour $+ / $+  $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ %SMP3.CNTR.avg.recd  $+ %SMP3.CNTR.txt.colour $+ MB 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  }
  .Individual Quick Stats: 
  ..Total of $round(%SMP3.CNTR.b.sent,0) MB ( $+ $round($calc(%SMP3.CNTR.b.sent /1000),2) GB) in %SMP3.CNTR.f.sent files sent since %SMP3.CNTR.date: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have sent a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.sent,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.sent /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.sent  $+ %SMP3.CNTR.txt.colour $+ files since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..Total of $round(%SMP3.CNTR.b.recd,0) MB ( $+ $round($calc(%SMP3.CNTR.b.recd /1000),2) GB) in %SMP3.CNTR.f.recd files received since %SMP3.CNTR.date: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have leeched/received a total of $+ %SMP3.CNTR.highlight $round(%SMP3.CNTR.b.recd,0)  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ $round($calc(%SMP3.CNTR.b.recd /1000),2)  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight %SMP3.CNTR.f.recd  $+ %SMP3.CNTR.txt.colour $+ files since $+ %SMP3.CNTR.highlight %SMP3.CNTR.date 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..-
  ..The largest file sent was %smp3.CNTR.maxsent MB: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The largest file I have sent was $+ %SMP3.CNTR.highlight %smp3.CNTR.maxsent  $+ %SMP3.CNTR.txt.colour $+ MB 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..The largest file received was %smp3.CNTR.maxrecd MB: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The largest file I have received/leeched was $+ %SMP3.CNTR.highlight %smp3.CNTR.maxrecd  $+ %SMP3.CNTR.txt.colour $+ MB 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..-
  ..The average size of files sent is %SMP3.CNTR.avg.sent MB: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The average size of a file sent is $+ %SMP3.CNTR.highlight %SMP3.CNTR.avg.sent  $+ %SMP3.CNTR.txt.colour $+ MB (The total number of MB's sent divided by the number of files sent) 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..The average size of files received is %SMP3.CNTR.avg.recd MB: say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour The average size of a file received is $+ %SMP3.CNTR.highlight %SMP3.CNTR.avg.recd  $+ %SMP3.CNTR.txt.colour $+ MB (The total number of MB's received divided by the number of files received) 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..-
  ..The total time spent sending files was $duration(%smp3.CNTR.t.sent) $+ : say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have spent a total of $+ %SMP3.CNTR.highlight $duration(%smp3.CNTR.t.sent)  $+ %SMP3.CNTR.txt.colour $+ sending files using mIRC. 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..The total time spent recieving files was $duration(%smp3.CNTR.t.recd) $+ : say 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have spent a total of $+ %SMP3.CNTR.highlight $duration(%smp3.CNTR.t.recd)  $+ %SMP3.CNTR.txt.colour $+ recieving files using mIRC. 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  ..-
  ..DCC-Counter Script has been sent %smp3.scriptsent times::
  .-
  .Stats and Configuration
  ..Settings And Colours: /dialog -m DCC_Counter_Config DCC_Counter_Config
  ..Quick Stats: /dialog -m DCC_Counter_Stats DCC_Counter_Stats
  .Test Colours: echo -a 4,2DCC-COUNTER COLOUR TEST: 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.left $+  $+ %SMP3.CNTR.txt.colour $+ , $+ %SMP3.CNTR.bg.colour I have just finished sending $+ %SMP3.CNTR.highlight A really big MP3 File.mp3  $+ %SMP3.CNTR.txt.colour $+ ( $+ 103 MB) to $+ %SMP3.CNTR.highlight Mr_Rogers $+ .   $+ %SMP3.CNTR.txt.colour $+ I have now sent a total of $+ %SMP3.CNTR.highlight 4353  $+ %SMP3.CNTR.txt.colour $+ MB ( $+ $DCC.Convert(%SMP3.CNTR.highlight) $+ 4.3  $+ %SMP3.CNTR.txt.colour $+ GB) in $+ %SMP3.CNTR.highlight 3532 $+  $+ %SMP3.CNTR.txt.colour files since $+ %SMP3.CNTR.highlight 01/01/01 1, $+ %SMP3.CNTR.bg.colour $+ %SMP3.CNTR.right
  .-
  .Reset
  ..Reset DCC Counter Values
  ...Clear All Values: {
    set %SMP3.CNTR.b.sent 0
    set %SMP3.CNTR.f.sent 0
    set %SMP3.CNTR.b.recd 0
    set %SMP3.CNTR.f.recd 0
    set %smp3.CNTR.t.recd 0
    set %smp3.CNTR.t.sent 0
    set %SMP3.Scriptsent 0
    set %smp3.CNTR.maxrecd 0
    set %smp3.CNTR.maxsent 0
    set %SMP3.CNTR.date $date
    writeini $DCC.Logfile Totals TotalRecieved 0
    writeini $DCC.Logfile Totals TotalSent 0
    writeini $DCC.Logfile Totals Numsent 0
    writeini $DCC.Logfile Totals Numrecieved 0
    writeini $DCC.Logfile Totals TimeSent 0
    writeini $DCC.Logfile Totals TimeRecieved 0
    writeini $DCC.Logfile Date DateStart $date
    writeini $DCC.Logfile ScriptSent Number 0
    writeini $DCC.Logfile MaxSize Sent 0
    writeini $DCC.Logfile MaxSize Recieved 0
  }
  .-
  .Unload This!: { DCC.ScriptUnload }
}